root/veekun/trunk/t/dex-search-pokemon.t

#!/usr/bin/perl

use strict;
use warnings;
use lib 'lib';

use Test::More tests => 35;

BEGIN { $ENV{CATALYST_DEBUG} = 0; }
BEGIN { use_ok 'Catalyst::Test', 'Vee' }
BEGIN { use_ok 'Vee::Controller::Dex::Search' }

sub search_ok;

### Simple search tests; these get slightly more complex as they go on, and in
### general I tried to keep the resultset small so it's easy to verify manually

ok request('/dex/pokemon/search')->is_success, "Pokemon search page loads";

search_ok { name => 'eon' },
    [qw/ 5 134 135 136 196 197 352 395 456 457 470 471 /],
    "Name substring";

search_ok { name => '???' },
    [qw/ 89 151 /],
    "Name with wildcards";

search_ok { ability => 'Drizzle' },
    [qw/ 382 /],
    "Ability";

search_ok { color => 'black', habitat => 'urban' },
    [qw/ 197 353 354 /],
    "Color and habitat";

search_ok { name => 'eon', evo_stage => 'base' },
    [qw/ 352 456 /],
    "Baseforms (+ name)";

search_ok { name => 'char', evo_stage => 'final' },
    [qw/ 6 /],
    "Final forms (+ name)";

# Gender dropdown had a few problems at one point, so I gave it several tests
search_ok { gender_rate => 254, generation => 0 },
    [qw/ 29 30 31 113 115 124 /],
    "Female-only (+ generation)";

search_ok { name => 'voltorb', gender_rate => 'not255' },
    [qw/ /],
    "Any gender (+ name)";

search_ok { name => 'eevee', gender_rate => 255 },
    [qw/ /],
    "No gender (+ impossible name)";

# Likewise with the breeding; that's gone wrong several times
search_ok { breed_mode => 'and', breed => [1, 2], evo_stage => 'base' },
    [qw/ 7 79 131 158 258 /],
    "Two different egg groups with 'and' (+ baseform)";

search_ok { breed_mode => 'and', breed => [13, 13] },
    [qw/ 132 /],
    "Two identical egg groups with 'and'";

search_ok { breed_mode => 'and', breed => [13, 0] },
    [qw/ 132 /],
    "One egg group plus n/a with 'and'";

search_ok { breed_mode => 'and', breed => [13, 5] },
    [qw/ /],
    "Two different egg groups with 'and' that can't occur together";

search_ok {
        breed_mode => 'or',
        breed      => [9, 11],
        evo_stage  => 'base',
        generation => 0,
    },
    [qw/ 72 88 90 92 98 109 120 138 140 /],
    "Two different egg groups with 'or' (+ generation and baseform)";

search_ok { generation => 2, basedex => 3 },
    [qw/ 265 266 267 268 269 278 279 298 307 308 315 339 340 349 350 358 /],
    "Generation and base Pokedex";

# Types are another common problem area
search_ok { name => 'eon', type_mode => 'any', type => [qw/ fire /] },
    [qw/ 5 136 /],
    "Single type with 'any' (+ name)";

search_ok { name => 'eon', type_mode => 'any', type => [qw/ fire water /] },
    [qw/ 5 134 136 395 456 457 /],
    "Two types with 'any' (+ name)";

search_ok { name => 'eon', type_mode => 'any', type => [qw/ fire water electric /] },
    [qw/ 5 134 135 136 395 456 457 /],
    "Three types with 'any' (+ name)";

search_ok { type_mode => 'all', type => [qw/ bug dragon /] },
    [qw/ /],
    "Two types with 'all' that never occur";

search_ok { type_mode => 'all', type => [qw/ ghost dragon /] },
    [qw/ 487 /],
    "Two types with 'all'";

search_ok { type_mode => 'all', type => [qw/ dragon ghost /] },
    [qw/ 487 /],
    "Same two types with 'all', reversed (i.e. order doesn't matter)";

search_ok { type_mode => 'all', type => [qw/ normal flying psychic /] },
    [qw/ /],
    "Three types with 'all'";

# Moves have a lot of possibilities; I just try a few easy ones here
search_ok { move => 'judgment' },
    [qw/ 493 /],
    "Single move";

search_ok { move => 'judgment', move_method => [qw/ egg machine tutor /] },
    [qw/ /],
    "Single move not by leveling up";

search_ok { move => 'judgment', move_version => [qw/ rb y gs c rusa frlg e /] },
    [qw/ /],
    "Single move by not in D/P";

search_ok { move => [qw/ splash tackle /], move_version => 'rb' },
    [qw/ 129 /],
    "Two moves in a specific generation";

# Similar for the stats; these all work the same so whatever
search_ok { stat_hp_lb => 250 },
    [qw/ 113 242 /],
    "Lower bound on HP";

# Height and weight had some rounding issues
search_ok { generation => 1, height_lb => 16, height_ub => 16 },
    [qw/ 182 183 187 194 220 238 /],
    "Exact height in inches (+ generation)";

search_ok { height_lb => '0.2m', height_ub => '0.2m' },
    [qw/ 50 177 298 406 412 433 492 /],
    "Exact height in meters";

search_ok { height_lb => '20cm', height_ub => '20cm' },
    [qw/ 50 177 298 406 412 433 492 /],
    "Exact height in centimeters";

# Quick sorting checks
search_ok { name => 'q', sort => 'stat_avg' },
    [qw/ 155 7 156 284 195 211 416 31 384 /],
    "Sorting by average stat";

search_ok { name => 'q', sort => 'id', sort_desc => 'on' },
    [qw/ 416 384 284 211 195 156 155 31 7 /],
    "Reverse sort by id";

sub search_ok {
    my ($params, $expected, $test_name) = @_;

    if (not $params->{sort}) {
        # sort by id for simplicity
        $params->{sort} = 'id';
        delete $params->{sort_desc};
    }

    my $context = Vee->prepare;
    $context->req->params($params);
    Vee::Controller::Dex::Search->pokemon_search($context);

    my $pokemon_rows = $context->stash->{results} || [];
    my @pokemon = map { $_->id } @$pokemon_rows;

    is_deeply \@pokemon, $expected, $test_name;
}