root/veekun/trunk/t/dex-search-moves.t

#!/usr/bin/perl

use strict;
use warnings;
use lib 'lib';

use Test::More tests => 16;

BEGIN { $ENV{CATALYST_DEBUG} = 0; }
BEGIN { use_ok 'Catalyst::Test', 'Vee' }
BEGIN { use_ok 'Vee::Controller::Dex::Search' }

sub search_ok;

### Same idea as Pokemon search tests

ok request('/dex/moves/search')->is_success, "Move search page loads";

search_ok { name => 'fire' },
    [qw/ 7 83 126 221 424 /],
    "Name substring";

search_ok { name => '???' },
    [qw/ 15 19 91 /],
    "Name with wildcards";

search_ok { name => 'fire', class => 'physical' },
    [qw/ 7 221 424 /],
    "Damage class (+ name)";

search_ok { class => 'special', type => 'dark' },
    [qw/ 399 /],
    "Type (+ damage class)";

search_ok { type => 'dragon', generation => 1 },
    [qw/ 200 225 239/],
    "Generation (+ type)";

search_ok { type => 'steel', generation => 0 },
    [qw/ /],
    "Impossible generation + type";

search_ok { pokemon => [qw/ flareon charizard /], move_method => 'level' },
    [qw/ 43 52 53 83 99 184 424 /],
    "Multiple Pokemon, by level";

search_ok { pokemon => 'ditto' },
    [qw/ 144 /],
    "Single Pokemon";

search_ok { pokemon => 'charizard', move_method => 'tutor', move_version => 'c' },
    [qw/ 53 /],
    "Single Pokemon, via tutor, in Crystal";

search_ok { power_lb => 200 },
    [qw/ 120 153 /],
    "Lower bound on power";

search_ok { power_lb => 14, power_ub => 16 },
    [qw/ 3 20 31 35 40 42 83 140 250 292 328 /],
    "Lower and upper bounds on power";

search_ok { accuracy_lb => 30, accuracy_ub => 30 },
    [qw/ 12 32 90 329 /],
    "Exact accuracy";

search_ok { name => 'fire', sort => 'name' },
    [qw/ 126 424 7 83 221 /],
    "Sorting (+ name)";

# TODO: This is remarkably similar to the Pokemon search sub!  Generalize and
# throw it in Veekun::Test::*.
sub search_ok {
    my ($params, $expected, $test_name) = @_;

    if (not $params->{sort}) {
        # sort by id for simplicity
        $params->{sort} = 'id';
        delete $params->{sort_desc};
    }

    my $context = Vee->prepare;
    $context->req->params($params);
    Vee::Controller::Dex::Search->move_search($context);

    my $move_rows = $context->stash->{results} || [];
    my @moves = map { $_->id } @$move_rows;

    is_deeply \@moves, $expected, $test_name;
}