root/veekun/trunk/t/dex-pokemon.t

#!/usr/bin/perl

use strict;
use warnings;
use lib 'lib';

use Test::More tests => 16;

BEGIN { $ENV{CATALYST_DEBUG} = 0; }
BEGIN { use_ok 'Catalyst::Test', 'Vee' }
BEGIN { use_ok 'Vee::Controller::Dex' }

ok request('/dex/pokemon/latias')->is_success, "Pokemon page loads";

# To make this (fairly) simply, I'll do most tests on an RBY Pokemon (me!) and a
# handful of generational tests on a DP Pokemon
my $c_eevee   = Vee->prepare;
$c_eevee->req->args->[0] = 'eevee';
Vee::Controller::Dex->pokemon($c_eevee);

my $c_lucario = Vee->prepare;
$c_lucario->req->args->[0] = 'lucario';
Vee::Controller::Dex->pokemon($c_lucario);

my $s_eevee   = $c_eevee->stash;
my $s_lucario = $c_lucario->stash;

is $s_eevee->{pid}, 133, "Padded id is fine";
isa_ok $s_eevee->{this}, 'Vee::Schema::Pokemon', '$this';
is $s_eevee->{generation}, 0, "RBY generation correct";
is $s_lucario->{generation}, 3, "DP generation correct";

is $s_eevee->{evtree}{width}, 7, "Evolution tree width is correct";
is_deeply [ map { $_->{id} } @{$s_eevee->{evtree}{children}} ],
    [ 134, 135, 136, 196, 197, 470, 471 ],
    "Evolution tree children are correct";

is_deeply $s_eevee->{type_effects}, {
      bug       => 100,
      dark      => 100,
      dragon    => 100,
      electric  => 100,
      fighting  => 200,
      fire      => 100,
      flying    => 100,
      ghost     => 0,
      grass     => 100,
      ground    => 100,
      ice       => 100,
      normal    => 100,
      poison    => 100,
      psychic   => 100,
      rock      => 100,
      steel     => 100,
      water     => 100,
    }, "Type effects correct";


is sprintf('%.1f', $s_eevee->{stat_average}), 54.2, "Stat average calculates correctly";
is sprintf('%.1f', $s_eevee->{stat_percentiles}{average}), 27.4, "Stat average percentile calculates correctly";

# XXX: I guess not all the flavor text is really needed any more?
isnt $s_eevee->{flavors}{d}, '', "Flavor text exists";
# TODO
like $s_eevee->{flavors}{d}, qr/^A rare Pok.{1,3}mon that adapts to harsh environments by taking on different evolutionary forms\.$/, "Flavor text is correct, ignoring the accent";
ok $s_eevee->{flavors}{d} eq $s_eevee->{flavors}{p}, "Diamond and Pearl flavor text is identical";

# TODO: Test locations once those are figured out

# TODO: Any way to flesh these out without just doing one big is_deeply?
# These are just spot checks for arbitrary moves.
is $s_eevee->{moves}{level}[-1]{move_id}, 376, "Eevee's last move is Trump Card";

#use Data::Dumper; $Data::Dumper::Maxdepth = 3; warn Dumper $s_eevee;