root/veekun/trunk/lib/Vee/Utils/Forum.pm

package Vee::Utils::Forum;

use strict;
use warnings;

use Exporter 'import';
our @EXPORT = qw/can_post can_thread toggleflag/;

=head1 NAME

Vee::Utils::Forum - Forum utilities

=head1 SYNOPSIS

Coming soon

=head1 DESCRIPTION

Currently, this file just contains shortcuts for checking posting permissions.
It may later be replaced, merged elsewhere, removed, or mauled by Latiases.

=head1 FUNCTIONS

=head2 can_post

Returns true if the current user can post on the given thread, false otherwise.

=cut

sub can_post {
    my ($c, $thread) = @_;

    return undef if $thread->flags =~ /locked/
        and not $c->can_i(override_thread_locked => $thread->forum->id);

    return undef if Vee::Utils::in( $thread->forum->accessibility => qw/archive hidden/ )
        and not $c->can_i('override_forum_' . $thread->forum->accessibility => $thread->forum->id);

    return $c->can_i(create_post => $thread->id);
}

=head2 can_thread

Returns true if the current user can create threads in the given forum, false
otherwise.

=cut

sub can_thread {
    my ($c, $forum) = @_;

    return undef if $forum->accessibility ne 'normal'
        and not $c->can_i('override_forum_' . $forum->accessibility => $forum->id);

    return $c->can_i(create_thread => $forum->id);
}

=head2 toggleflag

Adds or removes a flag for a thread/post.

NOTE: This should work for toggling multiple flags *only* if you
pass $flag in the same order as it is in the SET().
PS: SET() is useful, but retarded (hence all the regexes).

=cut

sub toggleflag {
    my ($object, $flag) = @_;
        
        return undef unless defined ($object && $flag);
        if ($object->flags =~ /$flag/) {
            # flag matched, unset it
                if ($object->flags =~ /,$flag/) { $flag =~ s/$flag/,$flag/g }
                elsif ($object->flags =~ /$flag,/) { $flag =~ s/$flag/$flag,/g }
                $object->flags(\"REPLACE(flags, '$flag', '')");
        } else {
            # flag not matched, set it
                $flag = ",$flag" if $object->flags;
                $object->flags(\"CONCAT(flags, '$flag')");
        }
        $object->update;
}

=head1 AUTHOR

Maintainer: Alex "Eevee" Munroe (C<veekun@veekun.com>)

See the included F<AUTHORS> file for a full list of contributers.

=head1 LICENSE

See the included F<LICENSE> file.

=cut

1;