root/veekun/trunk/lib/Vee/Schema/Threads.pm @ 350

package Vee::Schema::Threads;

use strict;
use warnings;
use base 'DBIx::Class';

=head1 NAME

Vee::Schema::Threads - DBIC class for the C<threads> table

=cut

__PACKAGE__->load_components(qw/ ResultSetManager Core /);
__PACKAGE__->table('threads');
__PACKAGE__->add_columns(qw/
  id forumid subject blurb firstpostid lastpostid lasttime postct hitct flags
/);
__PACKAGE__->set_primary_key('id');

__PACKAGE__->belongs_to(forum => 'Vee::Schema::Forums', 'forumid');
__PACKAGE__->has_many(posts => 'Vee::Schema::Posts', 'threadid');
__PACKAGE__->belongs_to(lastpost => 'Vee::Schema::Posts', 'lastpostid');
__PACKAGE__->belongs_to(firstpost => 'Vee::Schema::Posts', 'firstpostid');
__PACKAGE__->has_many(thread_views => 'Vee::Schema::ThreadViews', 'thread_id', { join_type => 'LEFT' });

=head1 METHODS

=head2 search_announcements

Returns a resultset of all the threads flagged as announcements.

=cut

sub search_announcements : ResultSet {
    my ($self) = @_;
    
    return $self->search(
        [ \ 'FIND_IN_SET("announcement", me.flags) AND NOT FIND_IN_SET("deleted", me.flags)' ],
        { prefetch => [ 'forum', { firstpost => 'user', lastpost => 'user' } ] }
    );
}

=head2 read_ids($user)

Returns a list of all thread ids the given user has read.

=cut

sub read_ids : ResultSet {
    my ($self, $user) = @_;

    return $self->search( {
        'thread_views.last_viewed' => \'>= me.lasttime',
        'thread_views.user_id'     => $user->id,
    }, {
        join    => 'thread_views',
        columns => [qw[ id ]],
    } )->get_column('id')->all;
}

=head1 SEE ALSO

L<Vee::Schema>, L<DBIx::Class>

=head1 AUTHOR

Maintainer: Alex "Eevee" Munroe (C<veekun@veekun.com>)

See the included F<AUTHORS> file for a full list of contributers.

=head1 LICENSE

See the included F<LICENSE> file.

=cut

1;