root/veekun/trunk/lib/Vee/Schema/Moves.pm @ 350

package Vee::Schema::Moves;

use strict;
use warnings;
use base 'DBIx::Class';

=head1 NAME

Vee::Schema::Moves - DBIC class for the C<moves> table

=cut

__PACKAGE__->load_components('Core');
__PACKAGE__->table('moves');
__PACKAGE__->add_columns(qw/
    id
    name
    name_jp
    name_romaji
    type
    power
    pp
    acc
    target
    class
    flags
    combos
    effect_chance
    kind
    status
    move_effect_id
    gameblurb
    dpblurb
    contype
    coneffect
    notes
/);
__PACKAGE__->set_primary_key('id');

__PACKAGE__->belongs_to(contest => 'Vee::Schema::ContestMoves', 'coneffect');
__PACKAGE__->belongs_to(effect => 'Vee::Schema::MoveEffects', 'move_effect_id');
__PACKAGE__->has_many(pokemoves => 'Vee::Schema::PokeMoves', 'moveid');

=head1 METHODS

=head2 priority

Returns the priority of the given move.  Only exists for consistency, as this
is the only data commonly accessed via C<%MoveData> that is actually a column
of C<move_effects>.

=cut

sub priority {
    my ($self) = @_;
    return $self->effect->priority;
}

=head2 description

Returns the full description for this move.  Applies C<_format_description>
effects, and converts tab-delimited tables to HTML.

=cut

sub description {
    my ($self) = @_;

    my $desc = $self->_format_description( $self->effect->description );
    my @lines = split /\n/, $desc;

    my $table_open = 0;
    for my $line (@lines) {
        if ($line =~ /\t/) {
            $line =~ s[\t][</td><td>]g;
            $line = "<tr><td>$line</td></tr>";
            $line = "<table>\n$line" if not $table_open;
            $table_open = 1;
        } else {
            $line = "<p>$line</p>";
            $line = "</table>\n$line" if $table_open;
            $table_open = 0;
        }
    }
    push @lines, "</table>" if $table_open;

    return join "\n", @lines;
}

=head2 blurb

Returns a short blurb for this move, suitable for putting in a move table.
Applies C<_format_description> effects.

If this move's move effect has no blurb, the full description will be used
instead.  This should no longer happen, but was necessary for some degree of
completion when the blurbs were still being written.

=cut

sub blurb {
    my ($self) = @_;

    return $self->_format_description(
        $self->effect->blurb || $self->effect->description
    );
}

=head2 _format_description($text)

Inserts this move's effect chance and priority into the provided string, if
applicable.  Used by C<description> and C<blurb>.

=cut

sub _format_description {
    my ($self, $text) = @_;

    # effect chance
    $text =~ s/a chance to/a ${\( $self->effect_chance )}% chance to/g
        if $self->effect_chance;

    if ($self->effect->priority < 0) {
        $text = "Goes last.  $text";
    } elsif ($self->effect->priority > 0) {
        $text = "Goes first.  $text";
    }

    return $text;
}

=head1 SEE ALSO

L<Vee::Schema>, L<DBIx::Class>

=head1 AUTHOR

Maintainer: Alex "Eevee" Munroe (C<veekun@veekun.com>)

See the included F<AUTHORS> file for a full list of contributers.

=head1 LICENSE

See the included F<LICENSE> file.

=cut

1;