root/veekun/trunk/lib/Vee/Schema/Forums.pm @ 406

package Vee::Schema::Forums;

use strict;
use warnings;
use base 'DBIx::Class';

=head1 NAME

Vee::Schema::Forums - DBIC class for the C<forums> table

=cut

__PACKAGE__->load_components(qw/ ResultSetManager Core /);
__PACKAGE__->table('forums');
__PACKAGE__->add_columns(qw/
    id name last_post_id thread_count post_count flags accessibility description
/);
__PACKAGE__->set_primary_key('id');

__PACKAGE__->has_many(threads => 'Vee::Schema::Threads', 'forum_id');
__PACKAGE__->might_have(last_post => 'Vee::Schema::Posts', { 'foreign.id' => 'self.last_post_id' });

=head2 unread_ids($user)

Returns a list of all forum ids the given user has not read.

=cut

sub unread_ids : ResultSet {
    my ($self, $user) = @_;

    # ->get_column doesn't seem to work here; it tries 'SELECT id' and I get
    # ambiguity errors
    return map { $_->id } $self->search( {
        'threads.last_post_time'   => { '>' => $user->thread_view_cutoff },
        'thread_views.last_viewed' => [ undef, \'< threads.last_post_time' ],
    }, {
        # XXX: This is very naughty, but the only way to stuff the user id in
        # the ON clause
        from     => [
            { me => 'forums' },
            [
                [
                    { threads => 'threads' },
                    [
                        {
                            thread_views => 'thread_views',
                            -join_type => 'left'
                        }, { # ON
                            'thread_views.thread_id' => 'threads.id',
                            'thread_views.user_id' => $user->id,
                        },
                    ],
                ],
                { 'me.id' => 'threads.forum_id' },
            ],
        ],
        group_by => 'me.id',
        columns  => [qw[ me.id ]],
    } )->all;
}

=head1 SEE ALSO

L<Vee::Schema>, L<DBIx::Class>

=head1 AUTHOR

Maintainer: Alex "Eevee" Munroe (C<veekun@veekun.com>)

See the included F<AUTHORS> file for a full list of contributers.

=head1 LICENSE

See the included F<LICENSE> file.

=cut

1;