root/veekun/trunk/lib/Vee/Schema/EvoChains.pm

package Vee::Schema::EvoChains;

use strict;
use warnings;
use base 'DBIx::Class';

=head1 NAME

Vee::Schema::EvoChains - DBIC class for the C<evo_chains> table

=cut

__PACKAGE__->load_components('Core');
__PACKAGE__->table('evo_chains');
__PACKAGE__->add_columns(qw/
    id
    growth_rate
    steps
    baby_item
/);
__PACKAGE__->set_primary_key('id');

__PACKAGE__->has_many(pokemon => 'Vee::Schema::Pokemon', 'evo_chain_id');

=head2 baby_form

Returns the baby Pokemon in this chain, if any.

=cut

sub baby_form {
    my ($self) = @_;

    return $self->pokemon( \ 'FIND_IN_SET(flags, "baby")' )->single;
}

=head2 basic_form

Returns the basic form of this Pokemon.

=cut

sub basic_form {
    my ($self) = @_;

    return $self->pokemon(
        \ 'NOT FIND_IN_SET(flags, "baby")',
    {
        order_by => 'id ASC',
    })->first;
}

=head2 egg_forms

Returns any Pokemon that can result from a breeding in this chain.

=cut

sub egg_forms {
    my ($self) = @_;
    my @ret;

    my $baby_form  = $self->baby_form;
    if ($baby_form) {
        push @ret, $baby_form;
    }

    my $basic_form = $self->basic_form;
    if (not $baby_form
        or $self->baby_item)  # e.g. Munchlax with incense
    {
        push @ret, $basic_form;
    }

    return @ret;
}

=head1 SEE ALSO

L<Vee::Schema>, L<DBIx::Class>

=head1 AUTHOR

Maintainer: Alex "Eevee" Munroe (C<veekun@veekun.com>)

See the included F<AUTHORS> file for a full list of contributers.

=head1 LICENSE

See the included F<LICENSE> file.

=cut

1;