root/veekun/trunk/lib/Vee/Controller/Shoutbox.pm @ 406

package Vee::Controller::Shoutbox;

use strict;
use warnings;
use base 'Catalyst::Controller';

use Vee::Authorization;

=head1 NAME

Vee::Controller::Shoutbox - Shoutbox Controller

=head1 SYNOPSIS

See L<Vee>

=head1 DESCRIPTION

Catalyst Controller for viewing the shoutbox.

=head1 METHODS

=cut

=head2 list

Show a list of all shoutbox entries ever.

=cut

sub history : Path : Args(0) {
    my ($self, $c) = @_;
    my $s = $c->stash;
    my $skip = $s->{skip} = $c->req->params->{skip} || 0;

    $s->{page_title} = 'Shoutbox';
    $s->{extra_css} = 'index';

    $s->{shouts_rs} = $c->model('DBIC::Shoutbox')->search(undef, {
        order_by => 'time DESC',
        prefetch => ['user'],
        rows     => $c->site_opts->{page_sizes}{shoutbox},
        offset   => $skip,
    });
    
    $s->{shout_total} = $c->model('DBIC::Shoutbox')->count;

    $s->{template} = 'shoutbox.tt';
}

=head2 post

Posts some stupid spam  :(

=cut

sub post : Local : Args(0) {
    my ($self, $c) = @_;
    my $s = $c->stash;

    my $content = Vee::Utils::fix_newlines( $c->req->params->{content} );
    my $name    = $c->req->params->{name}
                || ($c->user ? $c->user->name : 'Anonymous');

    if (!$content) {
        $c->vee_abort("Sorry, no mimes allowed.");
    }

    (my $linect = $content) =~ tr/\x0a//cd;
    if (length($linect) >= 10) {  # TODO: make me a pref!
        $c->vee_abort("Your shoutbox entry has too many lines, sorry.");
    }
    
    # TODO: better spamproofing of some sort later, maybe?
    if ($content =~ m!<a |</a>|\[url=|\[/url\]!) {
        $c->vee_abort("Your shoutbox entry contains links.  This usually means you are a spambot, in which case you can shove your online poker ads where the sun don't shine.  If you are not, simply go back and try again without the code; HTML and bbcode don't work in the shoutbox anyway.");
    }

    $c->model('DBIC::Shoutbox')->create({
        name => $name,
        user_id => ($c->user ? $c->user->obj->id : undef),
        ip => Vee::Utils::inet_aton($c->req->address),
        time => time,
        content => $content,
    });

    $c->res->redirect( $c->uri_for('/') );
}

=head1 AUTHOR

Maintainer: Alex "Eevee" Munroe (C<veekun@veekun.com>)

See the included F<AUTHORS> file for a full list of contributers.

=head1 LICENSE

See the included F<LICENSE> file.

=cut

1;