root/veekun/trunk/lib/Vee/Controller/Gallery.pm

package Vee::Controller::Gallery;

use strict;
use warnings;
use base 'Catalyst::Controller';

use Image::Size;

=head1 NAME

Vee::Controller::Gallery - Gallery Controller

=head1 DESCRIPTION

Catalyst Controller to handle the gallery.

=head1 METHODS

=head2 index

Overview of recently uploaded works.

=cut

sub index : Path {
    my ($self, $c) = @_;
    my $s = $c->stash;

    $s->{recent_rs} = $c->model('DBIC::Gallery')->search(undef, { order_by => 'time DESC', rows => 40 });

    $s->{page_title}  = 'Gallery';
    $s->{extra_css}   = 'gallery';
    $s->{breadcrumbs} = [ 'Gallery' ];

    $s->{template} = 'gallery/index.tt';
}

=head2 view

View of a single uploaded work.

=cut

sub view : Path : Args(1) {
    my ($self, $c, $work_id) = @_;
    my $s = $c->stash;

    my $row = $c->model('DBIC::Gallery')->find($work_id)
        or $c->vee_abort('No work with id ', $work_id, ' exists.');

    $s->{this} = $row;

    $s->{page_title}  = 'Gallery Item';
    $s->{extra_css}   = 'gallery';
    $s->{breadcrumbs} = [
        '<a href="' . $c->uri_for('/gallery') . '">Gallery</a>',
        'Gallery Item'
    ];

    $s->{template} = 'gallery/view.tt';
}

=head2 upload

Upload a work.

=cut

sub upload : Local {
    my ($self, $c) = @_;
    my $s = $c->stash;

    if ($c->req->method ne 'POST') {
        $s->{template} = 'gallery/upload.tt';
        return;
    }

    # from here on down is actual uploady logic
    my $upload = $c->req->upload('file');
    my ($width, $height, $type) = imgsize($upload->fh);

    # TODO: check that it's one of a few basic types; sanity-check physical size and filesize; etc
    $c->vee_abort("Uploaded file ", $upload->filename, " is not a recognized image.")
        if not $width or not $height;

    # TODO: errors
    # TODO: filename
    my $filename = $upload->filename;
    $upload->copy_to( $c->path_to('root', 'uploads', $filename) );

    system 'convert', qw(-resize 100x100),  # TODO: config?
        $c->path_to('root', 'uploads',           $filename),
        $c->path_to('root', 'uploads', 'thumbs', $filename);

    my $new_obj = $c->model('DBIC::Gallery')->create({
        creatorid  => 3,
        filename   => $upload->filename,
        uploaderid => $c->user->obj->id,
        time       => time,
        hash => '',
        title => $upload->filename,
        description => $upload->filename,
        height => $height,
        width => $width,
        type => 'colored',
    });

    $c->flash->{success_msg} = "Successfully uploaded " . $c->vee_cleanse($upload->filename) . "!";

    # $c->res->redirect('/gallery/whatever/$new_obj');
    $c->res->redirect($c->uri_for('/gallery'));
}

=head1 AUTHOR

Maintainer: Alex "Eevee" Munroe (C<veekun@veekun.com>)

See the included F<AUTHORS> file for a full list of contributers.

=head1 LICENSE

See the included F<LICENSE> file.

=cut

1;