root/veekun/trunk/lib/Vee/Controller/Forum/Post.pm @ 406

package Vee::Controller::Forum::Post;

use strict;
use warnings;
use base 'Catalyst::Controller';
use Vee::BBCode;
use Vee::Utils;
use Vee::Utils::Forum;

=head1 NAME

Vee::Controller::Forum::Post - Post utilities Controller

=head1 SYNOPSIS

See L<Vee>

=head1 DESCRIPTION

Catalyst Controller for various post utilities (editing, deleting, nuking), and post flags.

=head1 METHODS

=cut


=head2 auto

=cut

sub auto : Private {
    my ($self, $c) = @_;
    
    if (!$c->user) {
        $c->vee_abort('You must be logged in to perform any of these actions.');
    }
    
    return 1;
}

=head2 utils

Code for post utilities (deleting, nuking, undeleting)

This code will probably undergo many changes. I am trying to optimize
it as much as possible to take up very few lines. Any assistance in
doing so is greatly appreciated.

=cut

sub utils : LocalRegex('^(\d*)/(delete|undelete|nuke)') : Args(0) {
    my ( $self, $c ) = @_;
    my ($post_id, $method) = @{ $c->req->captures };
    
    my $forum_id = undef;
    # This is the post to be deleted, as well as the entire result set of things to be modified
    my $post = $c->model('DBIC::Posts')->find({ 'me.id' => $post_id }, { prefetch => ['user', { 'thread' => 'forum' }], })
        or $c->vee_abort("There is no post with id of ", $post_id, ". Perhaps another admin nuked it?");
    $c->vee_abort("The post with id of ", $post_id, " has already been ", $method, "d.")
        if (($post->flags =~ /deleted/ && $method eq 'delete') || ($post->flags !~ /deleted/ && $method eq 'undelete'));
    $c->vee_abort("You don't have permission to ", $method, " this post.")
        unless (($c->user->obj->id == $post->user_id && $method ne 'nuke') || $c->can_i("post$method"));

    # Do everything in a transaction for rollback purposes
    my $action = $c->model('DBIC')->schema->txn_do( sub {
        my ($thread, $forum, $user) = ($post->thread, $post->thread->forum, $post->user);
        # If any of the post (or thread) counts are 0 or less, this will break. Of course, if that's the case, something is broken
        return undef unless (($forum->post_count >= 0 || $forum->thread_count >= 0 || $thread->post_count >= 0 || $user->post_count >= 0) || ($method eq 'undelete'));
        my $thread_postct = $c->model('DBIC::Posts')->count({ 'me.thread_id' => $post->thread_id, 'me.flags' => { '!=', 'deleted' } });
        # Unfortunately, this must be done here, since this needs to include deleted posts as well
        my ($last_post_id, $last_post_time) = ((map {($_->id)} $c->model('DBIC::Posts')->search({ 'thread.forum_id' => $forum->id, 'me.thread_id' => $post->thread_id }, { prefetch => 'thread', columns => [qw/me.id me.thread_id thread.forum_id/], order_by => 'me.time DESC' })), undef);

        if ($method eq 'nuke') { $c->model('DBIC::Posts')->search({ 'me.id' => $post_id })->delete; }
        else { toggleflag( $post, 'deleted' ) or return undef; } 

        # If there's only one post left, delete the thread as well
        if ($thread_postct > 1 && $last_post_id == $post->id) {
            ($last_post_time, $last_post_id) = map {($_->time, $_->id)} $c->model('DBIC::Posts')->search({ 'thread.forum_id' => $forum->id, 'me.thread_id' => $post->thread_id, 'me.flags' => { '!=', 'deleted' } }, { prefetch => 'thread', rows => 1, order_by => 'me.time DESC' });
        } elsif ($thread_postct <= 1) {
            #try moving this elsewhere later, i hate it here
            if ($method eq 'nuke') { $c->model('DBIC::Threads')->search({ 'me.id' => $post->thread_id })->delete; }
            elsif (($method eq 'undelete' && $thread_postct == 0) || ($method eq 'delete' && $thread_postct <= 1)) {
                toggleflag( $thread, 'deleted' ) or return undef;
            }
            ($last_post_time, $last_post_id) = map {($_->time, $_->id)} $c->model('DBIC::Posts')->search({ 'thread.forum_id' => $forum->id, 'thread.flags' => { '!=', 'deleted' }, 'me.flags' => { '!=', 'deleted' } }, { prefetch => 'thread', rows => 1, order_by => 'me.time DESC' });
            $forum_id = $forum->id;
            $last_post_id = 0 unless $last_post_id;
        }
            
        if (($method eq 'nuke' && $post->flags !~ /deleted/) || ($method eq 'delete')) { 
            $thread->post_count($thread->post_count - 1);
            $forum->post_count($forum->post_count - 1);
            $forum->thread_count($forum->thread_count - 1) unless ($thread_postct > 1);
            $user->post_count($user->post_count - 1);
        } elsif ($method eq 'undelete') {
            $thread->post_count($thread->post_count + 1);
            $forum->post_count($forum->post_count + 1);
            $forum->thread_count($forum->thread_count + 1) unless ($thread_postct > 1);
            $user->post_count($user->post_count + 1);
        }
        # Only update last post and time if this is actually the last post
        if ($last_post_time && $post->id == $thread->last_post_id) {
            $thread->last_post_id($last_post_id);
            $thread->last_post_time($last_post_time);
        }
        # Needs to be done here, in case the deleted post is the last post in a forum :(
        $forum->last_post_id($last_post_id) if $post->id == $forum->last_post_id;
        $thread->update if ($method ne 'nuke');
        $forum->update;
        $user->update;
    
        return $post;
    });

    $c->error("This error message should never be displayed unless someone is screwing with things; sorry.") unless $action;
    $c->res->redirect("/forum/" . (($forum_id) ? "$forum_id" : "post/$post_id"));
}

=head2 edits

Code for listing edits to a post.

=cut

sub edits : LocalRegex('^(\d*)/edits') {
    my ($self, $c) = @_;
    my ($s, $post_id) = ($c->stash, $c->req->captures->[0]);
    
    $c->vee_abort("You don't have permission to view post edits.") unless ($c->can_i('post_edits'));

    my $post   = $c->model('DBIC::Posts')->find({ 'me.id' => $post_id}, { prefetch => [qw/user edits/, { thread => 'forum' }], order_by => 'edits.time DESC' });
    
    $s->{post}      = $post;
    $s->{extra_css} = ['forum', 'bbcode'];
    $s->{template}  = 'forum/thread/edits.tt';
}

=head2 edit

Code for editing a post.

=cut

my $reply_fields = {
    content => { type => 'textarea', rows => '10', cols => '100' },
    id => { type => 'hidden' },
};

sub edit : LocalRegex('^(\d*)/edit') : Args(0) {
    my ($self, $c) = @_;
    my ($s, $post_id) = ($c->stash, $c->req->captures->[0]);
    
    my $post_rs = $c->model('DBIC::Posts')->search({ 'me.id' => $post_id }, { prefetch => 'user' })->single;
    $c->vee_abort("You must be logged in to edit posts.") unless $c->user;
    $c->vee_abort("You don't have permission to edit posts.") unless ($c->can_i('post_edit') || $c->user->obj->id == $post_rs->user_id);
    
    # Form submited stuff
    if ('post' eq lc $c->req->params->{submit}) {
        my ($parsed_message, @bbcode_errors) = Vee::BBCode::validate_bbcode( $c->req->params->{content} );
        if (@bbcode_errors) {
            $c->vee_abort("Your post contains invalid bbcode.  Please go back and fix it.");
        }
        $parsed_message = Vee::Utils::fix_newlines( $parsed_message );
        
        # If post wasn't edited, don't do anything further; results in redirect only
        unless ($parsed_message eq $post_rs->content) {
            my $post = $c->model('DBIC')->schema->txn_do( sub {
                my $edit = $c->model('DBIC::Edits')->create({
                    post_id     => $post_rs->id,
                    user_id     => $c->user->obj->id,
                    time        => time,
                    old_content => $post_rs->content,
                });
                
                $post_rs->last_edit_id( $edit->id );
                $post_rs->content($parsed_message);
                $post_rs->update;
                
                return $post_rs;
            });
        }
        $c->res->redirect( $c->uri('Forum', 'post', $post_rs->id) );
    }
    
    my $form = new Vee::Form(
        id => 'reply',
        fields => $reply_fields,
        params => $c->req->params,
        copy_params => 1,
    );
    $form->force( id => $post_rs->thread_id );
    $form->force( content => $c->req->params->{content} || $post_rs->content || '' );
    
    $s->{page_header} = "Edit Post";
    $s->{page_title}  = "Edit";
    $s->{post}        = $post_rs;
    $s->{user}        = $post_rs->user;
    $s->{form}        = $form;
    $s->{extra_css}   = [qw/forum bbcode/];
    $s->{template}    = 'forum/thread/edit.tt';
}


=head1 AUTHOR

Maintainer: Alex "Eevee" Munroe (C<veekun@veekun.com>)

See the included F<AUTHORS> file for a full list of contributers.

=head1 LICENSE

See the included F<LICENSE> file.

=cut

1;