root/veekun/trunk/lib/Vee/Controller/Forum.pm

package Vee::Controller::Forum;

use strict;
use warnings;
use base 'Catalyst::Controller';

use Scalar::Util qw/weaken/;
use List::Util qw/min/;
use Vee::Utils::Forum;

# TODO for flags:
# - consolidate checking for deletion/hiding and get it out of the main code
# - styling

=head1 NAME

Vee::Controller::Forum - Forum Controller

=head1 SYNOPSIS

See L<Vee>

=head1 DESCRIPTION

Catalyst Controller for forum viewing.

=head1 METHODS

=cut

=head2 auto

=cut

sub auto : Private {
    my ($self, $c) = @_;
    my $s = $c->stash;
    
    # TODO: hacky
    weaken $c;
    $s->{can_post} = sub { Vee::Utils::Forum::can_post($c, @_) };
}

=head2 list

List of forums.

=cut

sub list : Path : Args(0) {
    my ($self, $c) = @_;
    my $s = $c->stash;

    $s->{page_title} = 'Forums';
    $s->{link_name}  = 'forum';
    $s->{crumbs}     = [ '<a href="/forum">Forum Index</a>' ];
    $s->{extra_css}  = 'forum';

    $s->{announcements_rs} = $c->model('DBIC::Threads')->search_announcements;
    $s->{forums_rs}        = $c->model('DBIC::Forums')->search(undef, { prefetch => { last_post => 'user' } });

    # Grab a list of forums with unread threads
    if ($c->user) {
        my @unread_ids  = $c->model('DBIC::Forums')->unread_ids($c->user->obj);
        my %unread_hash = map { $_ => 1 } @unread_ids;

        $s->{is_unread} = sub { $unread_hash{$_[0]->id} };
    }

    $s->{template} = 'forum/index.tt';
}

=head2 view

Forum view: list of threads.

=cut

sub view : Path : Args(1) {
    my ($self, $c, $id) = @_;
    my $s = $c->stash;

    my $forum = $c->model('DBIC::Forums')->find($id)
        or $c->vee_abort('There is no forum with id ', $id, '.  You may have followed an old link, or might be playing with URLs.');

    my $skip = $c->req->params->{skip} || 0;
    my $perpage = $c->site_opts->{page_sizes}{threads};

    $s->{page_title}  = $forum->name . ' - Forums';
    $s->{page_header} = $forum->name;
    $s->{link_name}   = 'forum';
    $s->{extra_css}   = 'forum';
    $s->{crumbs}      = [ '<a href="/forum">Forum Index</a>', '<a href="/forum/'.$forum->id.'">'.$forum->name.'</a>' ];

    $s->{announcements_rs} = $c->model('DBIC::Threads')->search_announcements;
    $s->{forum}            = $forum;
    $s->{skip}             = $skip;
    $s->{threads_rs}       = $forum->search_related('threads', undef, {
        order_by => 'FIND_IN_SET("sticky", me.flags) > 0 DESC, last_post.time DESC',
        prefetch => { first_post => 'user', last_post => 'user' },
        offset   => $skip,
        rows     => $perpage,
    } );

    # TODO: ugly but for now I don't know the best way to clean it up
    $s->{threads_rs}       = $s->{threads_rs}->search(\ 'NOT FIND_IN_SET("deleted", me.flags)') unless $c->can_i(override_thread_deleted => $forum->id);

    # Grab a list of unread threads in this forum
    if ($c->user) {
        my @unread_ids  = $forum->search_related('threads')
                                ->unread_ids($c->user->obj);
        my %unread_hash = map { $_ => 1 } @unread_ids;

        $s->{is_unread} = sub { $unread_hash{$_[0]->id} };
    }
    
    # form generation stuff
    my $reply_fields = {
        content => { type => 'textarea', rows => '10', cols => '100' },
        id => { type => 'hidden' },
        subject => { type => 'text', maxlength => 48 },
        blurb => { type => 'text', maxlength => 96 },
    };
    
    my $form = new Vee::Form(
        id => 'reply',
        fields => $reply_fields,
        params => $c->req->params,
        copy_params => 1,
    );
    $form->force( id => $forum->id );
    
    $s->{form}     = $form;
    $s->{template} = 'forum/view.tt';
}

=head2 thread

Thread view: list of posts.

=cut

# TODO: spit out an error if we're not actually inside the thread!
sub thread : Local : Args(1) {
    my ($self, $c, $id) = @_;
    my $s = $c->stash;

    my $thread = $c->model('DBIC::Threads')->find($id, { prefetch => 'forum' })
        or $c->vee_abort('There is no thread with id ', $id, '.');
    $thread->view_count( $thread->view_count + 1 ); $thread->update;

    if ($thread->flags =~ /deleted/ and not $c->can_i(override_thread_deleted => $thread->forum->id)) {
        $c->vee_abort('This thread has been deleted.');
    }
    
    my $filter = $c->req->params->{filter};
    my $skip = $c->req->params->{skip} || 0;
    
    my $filter_user;
    if ($filter) {
        $filter_user = $c->model('DBIC::Users')->search({ name => $filter })->first;
        if ($filter_user) {
            my $posts_shown = $c->model('DBIC::Posts')->count({ thread_id => $id, user_id => $filter_user->id });
        } else {
            push @{ $s->{error_msg} }, "Can't find user " . $c->vee_cleanse($filter) . " in the database.";
            undef $filter;
        }
    }
    
    my $perpage = $c->site_opts->{page_sizes}{posts};
    my $lastpage = ($skip + $perpage >= $thread->post_count);
    my $posts_rs = $c->model('DBIC::Posts')->search(
        { 'me.thread_id' => $id, ( $filter_user ? ( 'me.user_id' => $filter_user->id ) : () ) },
        { prefetch => [ 'user', { 'lastedit', 'user' } ], order_by => 'me.time ASC', offset => $skip, rows => $perpage + 1 }
    );
    my $post_count = $c->model('DBIC::Posts')->count({ 'me.thread_id' => $id, ( $filter_user ? ( 'me.user_id' => $filter_user->id ) : () ) });
    my @flags = split /,/, $thread->flags;
        
    $s->{physical_lastpost} = $thread->search_related('posts', undef, { order_by => [ 'time DESC', 'id DESC' ] })->single;

    ### Last-viewed time

    if ($c->user and not $filter) {
        my $thread_view = $c->model('DBIC::ThreadViews')->search({
            thread_id => $thread->id,
            user_id   => $c->user->obj->id,
        })->single;

        if ($thread_view) {
            $s->{last_viewed} = $thread_view->last_viewed;

            if ($s->{physical_lastpost} and
                $thread_view->last_viewed < $s->{physical_lastpost}->time)
            {
                $thread_view->last_viewed( $s->{physical_lastpost}->time );
                $thread_view->update;
            }
        } elsif ($s->{physical_lastpost}) {
            # eval'd due to very improbable but possible race condition: user
            # loads the same thread twice simultaneously
            eval {
                $c->model('DBIC::ThreadViews')->create({
                    thread_id   => $thread->id,
                    user_id     => $c->user->obj->id,
                    last_viewed => $s->{physical_lastpost}->time,
                });
            };
        }
    }

    # form generation stuff
    my $reply_fields = {
        content => { type => 'textarea', rows => '10', cols => '100' },
        id => { type => 'hidden' },
    };
    
    my $form = new Vee::Form(
        id => 'reply',
        fields => $reply_fields,
        params => $c->req->params,
        copy_params => 1,
    );
    $form->force( id => $thread->id );

    $s->{page_title}  = $thread->subject . ' - Forums';
    $s->{page_header} = $thread->subject;
    $s->{link_name}   = 'forum';
    $s->{crumbs}      = [ '<a href="/forum">Forum Index</a>', '<a href="/forum/'.$thread->forum->id.'">'.$thread->forum->name.'</a>', qq'<a href="/forum/thread/'.$thread->id.'">'.$thread->subject.'</a>' ];
    if ($filter_user) { push @{ $s->{crumbs} }, '<a href="/user/'.$filter_user->id.'">'.$filter_user->name.'</a>\'s posts' }
    $s->{extra_css}   = [ 'forum', 'bbcode' ];
    $s->{form}        = $form;
    $s->{flags}       = \@flags;
        
    $s->{forum}       = $thread->forum;
    $s->{thread}      = $thread;
    $s->{page_islast} = $lastpage;
    $s->{posts_rs}    = $posts_rs;
    $s->{post_count}  = $post_count;
    $s->{skip}        = $skip;
    $s->{filter}      = $filter;

    $s->{template} = 'forum/thread/view.tt';
}

=head2 post

Post "view": link to the corresponding post.

=cut

sub post : Local : Args(1) {
    my ($self, $c, $id) = @_;

    my $post = $c->model('DBIC::Posts')->find($id, { prefetch => { thread => 'forum' } })
        or $c->vee_abort('There is no post with id ', $id, '.');

    # slurp up the number of (visible) posts before the requested one
    my $offset = $c->model('DBIC::Posts')->count({
        thread_id => $post->thread_id,
        -or => [
            { time => $post->time, id => { '<', $post->id } },
            { time => { '<', $post->time } },
        ],
    });

    my $perpage = $c->site_opts->{page_sizes}{posts};
    my $skip = $offset - $offset % $perpage;
    $c->res->redirect( $c->uri('Forum', 'thread', $post->thread_id, ($skip ? { skip => $skip } : ()) ) . "#p$id" );
}

=head2 flags

Set flags for a thread.

=cut

sub thread_flags : LocalRegex('^thread/(\d*)/(announcement|sticky|locked)') : Args(0) {
    my ($self, $c) = @_;
    my ($thread_id, $flag) = @{ $c->req->captures };

    my $thread = $c->model('DBIC::Threads')->find($thread_id);

    toggleflag($thread, $flag)
        or $c->vee_abort("Whoops! Error setting flag '", $flag, "'. Not much more can be said about this.");
    $c->res->redirect($c->uri('Forum', 'thread', $thread_id));
}

=head2 mark_read

Mark everything on the whole forum read.

=cut

sub mark_read : Local : Args(0) {
    my ($self, $c) = @_;

    if ($c->req->method ne 'POST') {
        $c->vee_abort('This URL may only be requested by POST.');
    } elsif (not $c->user) {
        $c->vee_abort('You must be logged in to use this function.');
    }

    $c->user->thread_view_cutoff(time);
    $c->user->update;

    $c->model('DBIC::ThreadViews')->search({
        user_id => $c->user->obj->id
    })->delete;

    $c->res->redirect( $c->req->referer || $c->uri_for('/') );
}

=head1 AUTHOR

Maintainer: Alex "Eevee" Munroe (C<veekun@veekun.com>)

See the included F<AUTHORS> file for a full list of contributers.

=head1 LICENSE

See the included F<LICENSE> file.

=cut

1;